1 files changed, 60 insertions, 0 deletions
diff --git a/dev-python/pyface/pyface-4.3.0-r1.ebuild b/dev-python/pyface/pyface-4.3.0-r1.ebuild
new file mode 100644
index 00000000000..7dab97ae079
--- /dev/null
+++ b/dev-python/pyface/pyface-4.3.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# https://github.com/enthought/pyface/issues/40 confirms only py2.7
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Enthought Tool Suite: Traits-capable windowing framework"
+HOMEPAGE="https://github.com/enthought/pyface http://pypi.python.org/pypi/pyface"
+SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/traits-4.1[${PYTHON_USEDEP}]
+	|| (
+		dev-python/wxpython:*[${PYTHON_USEDEP}]
+		dev-python/PyQt4[${PYTHON_USEDEP}]
+		dev-python/pyside[${PYTHON_USEDEP}]
+	)"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/traitsui[${PYTHON_USEDEP}]
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+	)"
+
+DOCS=( docs/*.txt )
+
+python_compile_all() {
+	use doc && virtualmake -C docs html
+}
+
+python_test() {
+	export ETS_TOOLKIT=qt4
+	export QT_API=pyqt
+	# set nosetests to ignore tests unpassable by these vars.
+	VIRTUALX_COMMAND="nosetests" virtualmake -v -I 'composite_grid_model_test_case*' \
+		-I 'simple_grid_model_test_case*' \
+		-I 'test_split_editor_area_pane*'
+}
+
+python_install_all() {
+	find -name "*LICENSE*.txt" -delete
+	use doc && dohtml -r docs/build/html/*
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}