1 files changed, 40 insertions, 0 deletions
diff --git a/dev-python/pyftpdlib/pyftpdlib-1.3.0.ebuild b/dev-python/pyftpdlib/pyftpdlib-1.3.0.ebuild
new file mode 100644
index 00000000000..9f5e30fb487
--- /dev/null
+++ b/dev-python/pyftpdlib/pyftpdlib-1.3.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3} pypy )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python FTP server library"
+HOMEPAGE="http://code.google.com/p/pyftpdlib/ http://pypi.python.org/pypi/pyftpdlib"
+SRC_URI="http://pyftpdlib.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
+IUSE="examples ssl"
+
+DEPEND="ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )"
+RDEPEND="${DEPEND}"
+
+# Usual; requ'd for a sane testsuite run
+DISTUTILS_NO_PARALLEL_BUILD=1
+
+python_prepare_all() {
+	# http://code.google.com/p/pyftpdlib/issues/detail?id=292&thanks=292&ts=1400308829
+	# Disable failing test
+	sed -e 's:test_on_incomplete_file_received:_&:' -i test/test_ftpd.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" test/test_ftpd.py || die
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( demo/. )
+	distutils-r1_python_install_all
+}