1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/python-levenshtein/python-levenshtein-0.12.0.ebuild b/dev-python/python-levenshtein/python-levenshtein-0.12.0.ebuild
new file mode 100644
index 00000000000..d44c2a69119
--- /dev/null
+++ b/dev-python/python-levenshtein/python-levenshtein-0.12.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="python-Levenshtein"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Functions for fast computation of Levenshtein (edit) distance, and edit operations"
+HOMEPAGE="http://github.com/miohtama/python-Levenshtein/tree/
+	http://pypi.python.org/pypi/python-Levenshtein/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~x86"
+IUSE="doc"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND=""
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	if use doc; then
+		# Cannot assume user has a system py2 or pypy
+		if python_is_python3; then
+			die "The build of Levenshtein.html is not supported by python3"
+		else
+			einfo "Generation of documentation"
+			"${PYTHON}" "${FILESDIR}/genextdoc.py" Levenshtein || die "Generation of documentation failed"
+		fi
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( Levenshtein.html )
+	distutils-r1_python_install_all
+}