1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/wcsaxes/wcsaxes-0.3.ebuild b/dev-python/wcsaxes/wcsaxes-0.3.ebuild
new file mode 100644
index 00000000000..ffa13430688
--- /dev/null
+++ b/dev-python/wcsaxes/wcsaxes-0.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Framework for plotting astronomical and geospatial data"
+HOMEPAGE="http://wcsaxes.readthedocs.org https://pypi.python.org/pypi/wcsaxes"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_compile() {
+	distutils-r1_python_compile --use-system-libraries --offline
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx --offline
+}
+
+python_test() {
+	esetup.py --offline test
+}
+
+python_install() {
+	distutils-r1_python_install --offline
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/ )
+	distutils-r1_python_install_all --offline
+}