1 files changed, 40 insertions, 0 deletions
diff --git a/dev-python/wtforms/wtforms-2.0.1.ebuild b/dev-python/wtforms/wtforms-2.0.1.ebuild
new file mode 100644
index 00000000000..34afac6dc1f
--- /dev/null
+++ b/dev-python/wtforms/wtforms-2.0.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="WTForms"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Flexible forms validation and rendering library for python web development"
+HOMEPAGE="http://wtforms.simplecodes.com/ http://pypi.python.org/pypi/WTForms"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc"
+
+S="${WORKDIR}/${MY_P}"
+
+DEPEND="app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( >=dev-python/sphinx-0.6[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test || die "Tests failed for ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}