3 files changed, 55 insertions, 0 deletions
diff --git a/media-libs/liblrdf/Manifest b/media-libs/liblrdf/Manifest
new file mode 100644
index 00000000000..0afa442f21f
--- /dev/null
+++ b/media-libs/liblrdf/Manifest
@@ -0,0 +1 @@
+DIST liblrdf-0.5.0.tar.gz 283109 SHA256 013002b91ef209827fe99552b8c7f0b569cddb3d6f1439bedbd8bafe1956a93c
diff --git a/media-libs/liblrdf/liblrdf-0.5.0.ebuild b/media-libs/liblrdf/liblrdf-0.5.0.ebuild
new file mode 100644
index 00000000000..c9e602e3d93
--- /dev/null
+++ b/media-libs/liblrdf/liblrdf-0.5.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit autotools
+
+DESCRIPTION="A library for the manipulation of RDF file in LADSPA plugins"
+HOMEPAGE="http://github.com/swh/LRDF"
+SRC_URI="http://github.com/swh/LRDF/tarball/${PV} -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 hppa ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/openssl-1
+	media-libs/raptor:2
+	>=media-libs/ladspa-sdk-1.12"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_unpack() {
+	unpack ${A}
+	mv *-LRDF-* "${S}"
+}
+
+src_prepare() {
+	sed -i -e 's:usr/local:usr:' examples/{instances,remove}_test.c || die #392221
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_test() {
+	has_version media-plugins/swh-plugins && default #392221
+}
+
+src_install() {
+	default
+	rm -f "${ED}"usr/lib*/liblrdf.la
+}
diff --git a/media-libs/liblrdf/metadata.xml b/media-libs/liblrdf/metadata.xml
new file mode 100644
index 00000000000..7bbcd54ed8d
--- /dev/null
+++ b/media-libs/liblrdf/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>sound</herd>
+	<upstream>
+		<remote-id type="github">swh/LRDF</remote-id>
+	</upstream>
+</pkgmetadata>