1 files changed, 46 insertions, 0 deletions
diff --git a/sci-chemistry/wxmacmolplt/wxmacmolplt-7.4.2.ebuild b/sci-chemistry/wxmacmolplt/wxmacmolplt-7.4.2.ebuild
new file mode 100644
index 00000000000..c53a1940546
--- /dev/null
+++ b/sci-chemistry/wxmacmolplt/wxmacmolplt-7.4.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+WX_GTK_VER=2.8
+
+inherit autotools eutils wxwidgets
+
+DESCRIPTION="Chemical 3D graphics program with GAMESS input builder"
+HOMEPAGE="http://www.scl.ameslab.gov/MacMolPlt/"
+SRC_URI="http://www.scl.ameslab.gov/MacMolPlt/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="flash"
+
+RDEPEND="
+	>=media-libs/glew-1.5.3
+	media-libs/mesa
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl]
+	flash? ( media-libs/ming )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-glew.patch
+	sed \
+		-e "/^dist_doc_DATA/d" \
+		-i Makefile.am || die "Failed to disable installation of LICENSE file"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-glew \
+		$(use_with flash ming)
+}
+
+src_install() {
+	default
+	doicon resources/${PN}.png
+	make_desktop_entry ${PN} wxMacMolPlt ${PN} "Science;Education"
+}