blob: d6bf0d7775e2d215bc8d28223d4afd90c679ca38 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools systemd eutils readme.gentoo-r1 user
DESCRIPTION="Minimalistic Murmur (Mumble server)"
HOMEPAGE="https://github.com/umurmur/umurmur"
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV/_}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="gnutls libressl polarssl shm"
# ssl-provider precendence: polarssl, gnutls, libressl
# and openssl if none specified
DEPEND=">=dev-libs/protobuf-c-1.0.0_rc2
dev-libs/libconfig
polarssl? ( >=net-libs/polarssl-1.0.0 )
gnutls? ( !polarssl? ( >=net-libs/gnutls-3.0.0 ) )
libressl? ( !polarssl? ( !gnutls? ( dev-libs/libressl ) ) )
!gnutls? ( !polarssl? ( !libressl? ( dev-libs/openssl:0 ) ) )"
RDEPEND="${DEPEND}"
DOC_CONTENTS="
A configuration file has been installed at /etc/umurmur/umurmur.conf - you
may want to review it. See also\n
https://github.com/umurmur/umurmur/wiki/Configuration "
S="${WORKDIR}/${P/_}"
pkg_pretend() {
local ssl_provider=( )
use polarssl && ssl_provider+=( polarssl )
use gnutls && ssl_provider+=( gnutls )
use libressl && ssl_provider+=( libressl )
if [[ ${#ssl_provider[@]} -gt 1 ]] ; then
ewarn "More than one ssl provider selected (${ssl_provider[@]})"
ewarn "defaulting to ${ssl_provider[0]}."
fi
}
pkg_setup() {
enewgroup murmur
enewuser murmur "" "" "" murmur
}
src_prepare() {
default
eautoreconf
}
src_configure() {
local myconf
econf \
--with-ssl=$(usev polarssl || usev gnutls || echo openssl) \
$(use_enable shm shmapi)
}
src_install() {
local confdir
emake DESTDIR="${D}" install
newinitd "${FILESDIR}"/umurmurd.initd umurmurd
newconfd "${FILESDIR}"/umurmurd.confd umurmurd
systemd_dounit "${FILESDIR}"/umurmurd.service
dodoc AUTHORS ChangeLog
newdoc README.md README
confdir="/etc/umurmur"
insinto "${confdir}"
doins "${FILESDIR}"/umurmur.conf
# Some permissions are adjusted as the config may contain a server
# password, and /etc/umurmur will typically contain the cert and the
# key used to sign it, which are read after priveleges are dropped.
fperms 0750 "${confdir}"
fowners -R root:murmur "${confdir}"
fperms 0640 "${confdir}"/umurmur.conf
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
if use polarssl ; then
elog
elog "Because you have enabled PolarSSL support, umurmurd will use a"
elog "predefined test-certificate and key if none are configured, which"
elog "is insecure. See https://code.google.com/p/umurmur/wiki/Installing02x#Installing_uMurmur_with_PolarSSL_support"
elog "for more information on how to create your certificate and key"
fi
}
|
