proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 74 insertions, 0 deletions

diff --git a/app-cdr/xcdroast/xcdroast-0.98_alpha16-r1.ebuild b/app-cdr/xcdroast/xcdroast-0.98_alpha16-r1.ebuild
new file mode 100644
index 00000000000..6792f533782
--- /dev/null
+++ b/app-cdr/xcdroast/xcdroast-0.98_alpha16-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=2
+inherit gnome2-utils eutils
+
+DESCRIPTION="Lightweight cdrtools front-end for CD and DVD writing"
+HOMEPAGE="http://www.xcdroast.org/"
+SRC_URI="mirror://sourceforge/xcdroast/${P/_/}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="nls"
+
+RDEPEND=">=x11-libs/gtk+-2:2
+	app-cdr/cdrtools"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${P/_/}
+
+src_prepare() {
+	epatch "${FILESDIR}"/cdda2wav_version.patch \
+	  "${FILESDIR}"/fix_cddb_hidden_tracks.patch \
+	  "${FILESDIR}"/io_compile.patch
+
+	# fix Norwegian locales
+	mv po/{no,nb}.po || die
+	mv po/{no,nb}.gmo || die
+	sed -i -e 's/no/nb/' po/LINGUAS || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--enable-gtk2 \
+		--disable-dependency-tracking \
+		--mandir=/usr/share/man \
+		--sysconfdir=/etc
+}
+
+src_compile() {
+	emake PREFIX=/usr || die
+}
+
+src_install() {
+	emake PREFIX=/usr DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog README doc/{README*,DOCUMENTATION,FAQ,TRANS*} \
+		doc/manual/README.txt
+
+	insinto /usr/share/doc/${PF}/manual
+	doins doc/manual/xcdroast-manual.pdf
+
+	insinto /usr/share/icons/hicolor/48x48/apps
+	newins xpms/xcdricon.xpm xcdroast.xpm
+
+	make_desktop_entry xcdroast "X-CD-Roast" xcdroast "AudioVideo;DiscBurning"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}